Faber Timing Model

//@version=6
// Faber Timing Model — sort.finance. Fills at the signal bar's close, 0.02% fee a side,
// whole account per trade, as the backtest. History and indicator warm-up
// differ from the site's, so expect close to the same trades, not identical.
// The review dates count from the first bar on the chart, and TradingView's
// history starts somewhere other than the backtest's, so the reviews here
// fall on different bars from the site's.
strategy("Faber Timing Model", overlay=true,
     initial_capital=100, default_qty_type=strategy.percent_of_equity,
     default_qty_value=100, commission_type=strategy.commission.percent,
     commission_value=0.02, process_orders_on_close=true, pyramiding=0)

// The bar the current position opened on, and the bar the last one closed on.
var int entryBar = na
var int exitBar = -1

// ── Signals ──────────────────────────────────────────────────────────────
average = ta.sma(close, 210)
// Reviewed once a "month" — every 21st bar from the 210th on — and
// only a change between two reviews trades.
review = bar_index >= 209 and (bar_index - 209) % 21 == 0
var bool reviewed = false
var bool wasAbove = false
enterNow = false
exitNow = false
if review
    nowAbove = close > average
    if reviewed
        enterNow := nowAbove and not wasAbove
        exitNow := not nowAbove and wasAbove
    wasAbove := nowAbove
    reviewed := true

// ── Orders ───────────────────────────────────────────────────────────────
// Open on the first bar the entry holds while flat; close on the first
// later bar the exit holds; never reopen on the bar a position closed.
inTrade = strategy.position_size != 0
if inTrade and bar_index > entryBar and exitNow
    strategy.close("Long")
    exitBar := bar_index
else if not inTrade and bar_index > exitBar and enterNow
    strategy.entry("Long", strategy.long)
    entryBar := bar_index

// ── Drawing ──────────────────────────────────────────────────────────────
plot(average, "SMA 210", color=#4d8dff)